      SUBROUTINE SECLT (CARD,IUO,IOBS,B,NX,FATAL)

*** WRITE OBSERVATION EQUATION FOR DL/DT 
***       WHERE L IS LINE LENGTH (KIND = 31)

      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
      IMPLICIT INTEGER (I-N)
      PARAMETER (MXSSN = 9999)
      CHARACTER*80 CARD
      LOGICAL FATAL
      LOGICAL INSIDE
      LOGICAL GETSSN
      LOGICAL ADDCON
      LOGICAL LMSL,LSS,LUP
      LOGICAL LBB,LGF,LCS,LVD,LVA,LVZ,LVS,
     &        LVR,LVG,LVC,LIS,LPS,LPG,LDR,LOS,LAP
      DIMENSION B(*),NX(*)
      DIMENSION IC(31),C(31)
      DIMENSION LSTA(2)
      COMMON /CONST/ PI,PI2,RAD,RADSEC,TWOPI
      COMMON /OPT/ AX,E2,DMSL,DGH,VM,VP,CTOL,ITMAX,ITMIN,IMODE,
     &             LMSL,LSS,LUP
      COMMON /OPRINT/ CRIT,LBB,LGF,LCS,LVD,LVA,LVZ,LVS,
     &                LVR,LVG,LVC,LIS,LPS,LPG,LDR,LOS,LAP
      COMMON /STRUCT/ NSTA,NAUX,NUNK,IDIM,NSTAS,NOBS,NCON,NZ,NCD
      COMMON /CDGRID/ GRDLX, GRDUX, GRDLY, GRDUY, ICNTX, ICNTY,
     &                ITREF
      COMMON /VF/ VFACTR(31)

      JDUM = 0

      READ (CARD,1) ISSN,JSSN, OBSB, STD                      
    1 FORMAT(2X, I4,I4,2F8.4)
      STD = STD * DSQRT(VFACTR(31))

      IF (.NOT.GETSSN(ISSN,ISN) ) THEN
         CALL LINE (3)
         WRITE(6,10) CARD
   10    FORMAT('0ERROR - NO *80* OR *91* RECORD--',A80,/)
         RETURN
      ELSEIF (.NOT.GETSSN(JSSN,JSN) ) THEN
         CALL LINE (3)
         WRITE(6,10) CARD
         RETURN
      ENDIF
 
      LCNT = 2
      LSTA(1) = ISN
      LSTA(2) = JSN

      KIND = 31
      IOBS = IOBS + 1
      NOBS = NOBS + 1
      LENG = 0
      CALL ADDCD(IC,LENG,LSTA,LCNT,B,KIND)
      CALL FORMLT(ISN,JSN,B,C,OBS0)                      
      CALL COMPIC(IC,C,LENG)
      CMO = (OBS0 - OBSB)
      IF (IMODE .EQ. 0) CMO = 0.D0

        IF (.NOT.ADDCON(IC,LENG,NX)) THEN
          WRITE(6,666)
  666     FORMAT("OERROR - INSUFFICIENT STORAGE FOR CONNECTIVITY",/)
          CALL ABORT2
        ENDIF
        WRITE (IUO) KIND,ISN,JSN ,IC,C,LENG,CMO,OBSB,STD,
     &              IOBS,JDUM,JDUM,ITREF

*** ECHO OBSERVATION NUMBERS

      IF (LCS) THEN
        CALL LINE (1)
        WRITE (6,3) IOBS,CARD
    3   FORMAT (1X,I6,3X,A80)
      ENDIF
   
      RETURN
      END
